Enviada: Seg 16 Abr 2007 9:12:41 am Assunto: imprimir os layer e caracteristicas no properties manager
Estou querendo copiar todos os layers que estão aparecendo na janela do layer properties manager, com todas as caracteristicas que aparecem nome do layer, cor, linetype, linewight, plotstyle, para o word ou outro editor de texto pra poder imprimir e verificar os layer que foram criados um a um e suas caracteristicas.
Se houver uma maneira mais fácil, tô esperando uma solução.
Registro: Mar 11, 2003 Mensagens: 157 Localização: Mogi das Cruzes - SP
Status: Offline
Enviada: Seg 16 Abr 2007 1:31:43 pm Assunto:
Fácil
Abra a janela com os Layers.
Selecione todos (Clique com botão direito e escolha Select All).
Clique com botão direito e escolha Save Layer States.
Depois dê um nome para este New Layer States e clique em OK.
Em seguida clique com o botão dirteito novamente sobre os layers e escolha Export, isso vai permitir que vc salve um arquivo com o nome Nome que você deu.LAS.
Salve em uma pasta de seu sistema.
Vá nesta pasta e dê duplo clique, abrirá o bloco de notas com a lista e o status de seu layer. Você poderá abrir também a partir do Excel.
Avise-nos se deu certo.
____________ Ewerton B Luppo
Técnico Manutenção
Petrobras - UN-RECAP
Abrir a janela com os layers - OK
selecionar todos os layers - OK
escolher todos os layers e salvar com save layers estates - OK
dar um nome para o arquivo - OK
clicar com o botão direito sobre os layers e escolher export, - não apareceu esta opção, (Obs, meu autocad é um 2004 OK esqueci de informar a versão). Dai pra frente eu não consegui mais seguir os passos pois o autocad não deu a opção de exportar os aquivos
Registro: Mar 11, 2003 Mensagens: 157 Localização: Mogi das Cruzes - SP
Status: Offline
Enviada: Seg 16 Abr 2007 4:14:43 pm Assunto:
Acabei de ver.
Se a opção Save Layer State não lhe permitir salvar como arquivo EULLER.LAS, tente o botão State Manager para ver se tem opção de Salvar ou exportar ou então o Show Details para visualizar os detalher e capturar os dados.
____________ Ewerton B Luppo
Técnico Manutenção
Petrobras - UN-RECAP
OK, valeu, não saiu como eu queria, ficou muito desconfigurado más saiu, vou ver se consigo uma maneira de sair o que eu quero. se houver outra maneira tô na area,
Enviada: Ter 17 Abr 2007 5:54:41 pm Assunto: Lista de Layers
emonteiro,
É básica mas deve ajudar.
Código:
;;------------------------------------------------------------ --------------------------
;; ROTINA QUE CRIA UM ARQUIVO TXT (NOTEPAD.EXE - BLOCO DE NOTAS) COM TODOS OS LAYERS
;; EXISTENTES NO DESENHO. ESTE ARQUIVO É CRIADO NO DIRETÓRIO DE FUNCIONAMENTO DO AUTOCAD
;; TÍTULO ORIGINAL LYRX.LSP RENOMEADO PARA LAYERTXT.LSP
;;----------------------------------------------------- ---------------------------------
;; Tip1776: LYRX.LSP LAYER STATE EXPORT (c)2002, Lee Ambrosius
;;
;; Version 1.1
;; LYRX is a complete Layer State Export program to a text file.
;; The text file is then automatically opened for viewng and saving
;; to a different file name. Default file that is created everytime
;; is LYRX.txt and is placed in the working directory of AutoCAD.
(defun
C:LYRX ()
;; Grabs the value from the designated location in the DXF code
;; ie. (dxf 2 <ENTITY DATA>)
(defun DXF (CODE ELIST) (cdr (assoc CODE ELIST)))
;; Reset CSTATE to nil and STATIS to "" (an empty string)
(setq
CSTATE NIL
STATIS ""
) ;_ end of setq
;; Opening prompt of application
(prompt "\nExporting Layer list...")
;; Grab very first Layer entity in Layer Table
(setq ED (tblnext "LAYER" t))
;; Grab the first Layer name from table entity
(setq LAYNAM (DXF 2 ED))
;; Open the LYRX.TXT file for write
(setq FP (open "lyrx.txt" "w"))
;; Write the file header information
(write-line
"Layer name State Color Linetype"
FP
) ;_ end of write-line
(write-line
"--------------------------------------------------------------------- -----------------"
FP
) ;_ end of write-line
;; Keep looping while there is an entity in the layer table
(while (/= LAYNAM NIL)
;; If the Layer name is less than 32 characters then add some xtra spaces in the value
(while (< (strlen LAYNAM) 33) (setq LAYNAM (strcat LAYNAM " ")))
;; Get the Layer's color State (Positive - On or Negative - Off)
(setq COLOR (DXF 62 ED))
;; Get the Layer's States (Locked and/or Frozen)
(setq STATIS (DXF 70 ED))
;; Get the Layer's Line Type name
(setq LTYPE (DXF 6 ED))
;; Gets the Layers Color Value
(setq COLORT (itoa (abs COLOR)))
;; COLOR is a Negative Value so layer is Off
(if (< COLOR 0)
(setq CSTATE "Off")
) ;_ end of if
;; COLOR is a Positive Value so layer is On
(if (> COLOR 0)
(setq CSTATE "On")
) ;_ end of if
;; Layer is in the states of Locked and Frozen
(if (or (= STATIS 69) (= STATIS 5) (= STATIS 53))
(setq STATIS "/Locked and Frozen")
) ;_ end of if
;; Layer is in the state of Locked
(if (or (= STATIS 68) (= STATIS 4) (= STATIS 52))
(setq STATIS "/Locked")
) ;_ end of if
;; Layer is in the state of frozen
(if (or (= STATIS 65) (= STATIS 1) (= STATIS 49))
(setq STATIS "/Frozen")
) ;_ end of if
;; Layer is in the states of Unlocked and Thawed
(if (or (= STATIS 0) (= STATIS 48) (= STATIS 16))
(setq STATIS "")
) ;_ end of if
;; If the Layer states are less than 23 characters then add some extra spaces in the value
(setq LYRSTATE (strcat CSTATE STATIS))
(while (< (strlen LYRSTATE) 24)
(setq LYRSTATE (strcat LYRSTATE " "))
) ;_ end of while
;; If the Layer color is less than 14 characters then add some extra spaces in the value
(while (< (strlen COLORT) 15) (setq COLORT (strcat COLORT " ")))
;; Write layer information out to the LYRX.TXT file
(write-line (strcat LAYNAM LYRSTATE COLORT LTYPE) FP)
;; Reset CSTATE to nil and STATIS to "" (an empty string)
(setq
CSTATE NIL
STATIS ""
) ;_ end of setq
(setq LYR_DATA (strcat LAYNAM LYRSTATE COLORT LTYPE))
;; Grab the next Layer entity in Layer Table
(setq ED (tblnext "LAYER"))
;; Grab the Layer name from table entity
(setq LAYNAM (DXF 2 ED))
) ;_ end of while
;; Close the file LYRX.TXT for write
(close FP)
;; Launch NotePad with the LYRX.TXT file
(startapp "notepad.exe" "lyrx.txt")
(princ)
) ;_ end of defun
(defun
C:LYRX? ()
(textscr)
(prompt "\n")
(prompt
"\nCreated by Lee Ambrosius, HyperPics all rights reserved."
) ;_ end of prompt
(prompt "\nVisit HyperPics on the web at: www.hyperpics.com")
(prompt "\nDate: 3/14/00")
(prompt "\n")
(prompt "\nVersion 1.1")
(prompt "\n")
(prompt
"\nLYRX is a complete Layer State Export program to a text file."
) ;_ end of prompt
(prompt
"\nThe text file is then automatically opened for viewing and saving"
) ;_ end of prompt
(prompt
"\nto a different file name. The default file, which is created each time, "
) ;_ end of prompt
(prompt
"\nis LYRX.txt and is placed in the working directory of AutoCAD."
) ;_ end of prompt
(prompt "\n")
(princ)
) ;_ end of defun
(prompt "\n")
(prompt "\nCopyright(c) 2000 Layer Export tool.")
(prompt "\nAll rights reserved by HyperPics, www.hyperpics.com .")
(prompt "\nDigite LYRX para criar a lista de Layers.")
Registro: Feb 27, 2003 Mensagens: 2647 Localização: Brasil
Status: Offline
Enviada: Sex 20 Abr 2007 9:43:52 am Assunto:
Outra maneira mais "rústica" é digitar:
-layer e dar enter
? e dar enter
e ir dando enter, vai aparecer uma lista na janela de texto, expanda a janela (F2), copie e cole no bloco de notas ou word e imprima, veja um exemplo:
Command: -layer
Current layer: "0"
Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/MATerial/Plot/Freeze/Tha w/LOck/Unlock
/stAte]: ?
Enter layer name(s) to list <*>:
Layer name State Color Linetype Lineweight
------------------ ----------- ------------------ ------------ ------------
"0" on -P 7 (white) "Continuous" Default
"Layer1" off -P 1 (red) "Continuous" Default
"Layer2" Frozen -P 2 (yellow) "Continuous" Default
"Layer3" on -L-P 3 (green) "Continuous" Default
"Layer4" off -L-P 4 (cyan) "Continuous" Default
"Layer5" Frozen -P 5 (blue) "Continuous" Default
"Layer6" Frozen -L-P 6 (magenta) "Continuous" Default
"Layer7" Frozen -L-P 7 (white) "Continuous" Default
"Layer8" on -P 8 "Continuous" Default
Current layer: "0"
Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/MATerial/Plot/Freeze/Tha w/LOck/Unlock
/stAte]:
____________ Abraços,
Luciana Klein
Sócia-Fundadora CADKlein
Diretora AUGIbr
Autora Livro AutoCAD 2006 2D
Autora Livro AutoCAD 2008 2D/3D
Autora Livro AutoCAD 2010 2D/3D
AutoCAD 2009/10/11/2012 Certified Professional/Associate
www.lucianaklein.com/loja
____________ Abraços,
Luciana Klein
Sócia-Fundadora CADKlein
Diretora AUGIbr
Autora Livro AutoCAD 2006 2D
Autora Livro AutoCAD 2008 2D/3D
Autora Livro AutoCAD 2010 2D/3D
AutoCAD 2009/10/11/2012 Certified Professional/Associate
www.lucianaklein.com/loja
